Balanceo de carga MikroTik diferentes velocidades

Balanceo de carga Pcc de una o mas lineas

 
Un buen balanceo de carga es muy buscado por empresas  o wisp que desean balancear el trafico de  su red lan  hacia internet para poder usar correctamente sus dos lineas o mas de sus proveedores  , ahora muchas personas consideran que  el hacer un balanceo de  carga significa "sumar las lineas" que al hacer una balanceo de sus dos  o mas lineas y cuando hagan un speed test le mostrara la suma de todos los megas contratado de todos sus proveedores  o que  cuando descargen algun archivo  pesado les decargara a la suma de toda la velosidad contratada de todos sus proveedores  de servicio , eso es algo completamente falso.

Que es el balanceo de carga

El balanceo de carga divide  conexiones,  un  cliente puede generar 4  o 5 conexiones hacia internet 2 conexiones pueden salir por  la linea 1 y  3 por la linea 2  (la sumatoria de lineas  no existe) al hacer un balanceo se hace la divicion de conexiones de los clientes   hacia internet de esa es la forma es que el balanceo Pcc divide la carga de los clientes hacia internet

 
Veremos un ejemplo de  un balanceo de carga asimetrico , con dos lienas  una linea de 10 megas y la otra de 30 megas ,el conocer  de cuantos megas es cada  linea es muy importante porque  nos ayudara a poder hacer nuestro calculo para poder hacer nuestra configuracion de balanceo , datos como saver   en que puerto fisico esta  conectado cada linea ,  saver si el router del proveedor del cliente esta en modo router o modo bridge  son datos que  siempre tenemos que saver para que el balanceo sea los mas exacto posible posible

Datos importantes a considerar antes de hacer un balanceo

• Saber en que ether esta conectado fisicamente las lineas Wans  y  la red lan
• Saber si los routers del proveedor del cliente estan en modo bridge o modo router
• Saber  de cuanto es cada linea (saver en que ether esta conectado cada linea)

Asumiendo que  tenemos

• ether1 = 10 Megas
• ether2 = 30 Megas
• ether5 = Red Lan
• Los router de  su proveedor del cliente estan en modo router 

De preferencia  seria mejor que los router  del proveedor del cliente esten en modo bridge  y que el mikrotik reciba  la cuenta pppe ,la diferencia de hacer un balanceo con cuentas pppoe es solo el nombre de la interface  con la que se trabaja, teniendo en consideracion esta informacion  comensamos  ha hacer nuestro balanceo

Paso 1

Identificamos  las interface  en la opcion Interfaces

Paso 2

Nombramos las direcciones ips  a cada interface  en IP/Address

Address = indica la direccion de red que deseas nombrar , es nesesario poner una ip que no se este usando,  una ip que este en el mismo segmento de red en el que se encuentra el router del proveedor

Network = indica la red  ,esta obcion se autocompleta ya que ya  se mensiona en Address

Interface = hace referencia en que interface fisica se encuentra ese rango de ip

 /ip address
add address=192.168.1.2/24 comment="Wan 1" interface=ether1 network=192.168.1.0
add address=192.168.9.2/24 comment="Wan 2" interface=ether2 network=192.168.9.0
add address=10.10.10.1/24 comment=Lan interface=ether5 network=10.10.10.0

 

Es importante poner comentario a las  interfaces , direcciones y reglas para poder identificarlas en futuras configuraciones



 En caso trabajemos con cuentas pppoe no  tendremos que  agregar el address porque se agregaran automaticamente  y  les aparecera como  esta imaguen.



D = ip dinamica

Paso 3

Creamos las reglas de rutas estaticas de default gateway en IP/Route, para la salida de nuestro router  hacia internet
 
Dst Address =  Indica la red  que sera alcansable el 0.0.0.0/0 significa a todo (que alcansara a todas las redes que estan detras del gateway de nuestro cliente)

Gateway = Ip de nuestro de nuestro gateway  ,en nuestro  caso sera la ip de nuestro router de nuestro proveedor al que  estamos directamente conectado , recuerda que tenemos 2  lineas asi que haremos la  misma regla solo que cambiando el gateway




 En estos momentos veremos que solo funciona 1 ruta  porque fue la primera ruta que configuramos aunque  tengan la misma  distancia administrativa las dos reglas ,solo funcionara por la primera ruta que hayamos  configurado  ,si notan vemos tres reglas adicionales debajo de las 2 reglas  de ruteo que creamos  esas reglas se crean automaticamente cuando se asigna una ip a una interface , en la imagen vemos 1 de nuestra red lan y las otras dos de nuestras redes wan


Hay casos en el que nos encontraremos con routers del proveedor  que tengan la misma direccion  ip

• router A 192.168.1.1 
• router B 192.168.1.1 
• router C 192.168.1.1 

para forzar que una interface use un determinado  gateway  solo le añadimos el % y se espesifica la interface  por donde esta conectado fisicamente.

 add check-gateway=ping comment="Ruteo wan A" distance=1 gateway=192.168.1.1%ether1 routing-mark=to_ether2
add check-gateway=ping comment="Ruteo wan B" distance=1 gateway=192.168.1.1%ether2 routing-mark=to_ether2
add check-gateway=ping comment="Ruteo wan C" distance=1 gateway=192.168.1.1%ether3 routing-mark=to_ether2




seria mucho mejor si  tubieras acceso al router y cambiar a otro segmento de red

Paso 4

Nateamos las redes wan
Nos dirijimos a IP/Firewall/Nat y nateamos las dos redes wan en la pestaña  General

Srcnat = hace referencia al  origen  desde una red nateada, reemplaza la dirección de origen privada de un paquete IP con una nueva dirección IP pública a medida que viaja por el enrutador (el sentido del trafico)

Out.Interface =  espesifica la interface de salida del trafico(nuestra interface wan)




En la pestaña Action

Masquerade =  cambia el origen de los paquetes,  se usa para el accesso publico de redes privadas a redes publicas


 


hacemos  la misma regla con la otra linea

 

/ip firewall nat
add action=masquerade chain=srcnat comment="Wan 1" out-interface=ether1
add action=masquerade chain=srcnat comment="Wan 2" out-interface=ether2

Paso 5

Configuramos nuestros dns  para poder resolver los nombres de dominios
nos dirijirmos a IP/DNS  y  en la obcion server   ponemos los servidores Dns correspondientes  en mi caso puse el 8.8.8.8  ,8.8.4.4 ya que a mi parecer son los mas rapidos pero se puede poner cualquier otro servidor Dns,desabilitamos el  Allow Remote Requests si lo seleccionamos  estaremos usando nuestro mikrotik como servidor dns cache  algo que consume  recursos ,en caso nuestro router este expuesto a internet   cualquier persona podria usar nuestro router como   servidor Dns  el cual consumiria  innesesariamente recursos  de procesador y memoria ram y como resultado veremos lentitud en la red lan

/ip dns
set servers=8.8.8.8,8.8.4.4

Paso 6

Con esta configuracion , nuestro router ya tendria conexión a internet pero solo estaria activa  una linea wan ya que actualmente no se encuentra balanceando.

Paso 7

Nos dirigimos a hacer las marcas  de ruteo  en IP/Routes y nos encontraremos con las dos reglas  que anteriormente creamos  para las rutas de las wans ,ahora crearemos una regla con una marca de ruteo para cada linea de salida ,por tener orden en nuestra configuracion comentaremos todas nuestras reglas

Check Gateway = indica que periodicamente (cada 10 segundos) verifica la puerta de enlace  enviando una peticion eco  ICMP ,si no se resibe  ninguna respuesta  de la puerta de enlace  durante  10 segundos pasa a un modo de espera , despues de 2 tiempos de espera  la conexion se considera  inalcanzable ,cuando se recibe la respuesta se considera alcansable y se restablece  el contador de tiempo

Routing Mark =  identifica el dato de todos los paquetes de esa conexion y identificados con la marca de ruteo to_ether1  seran enviado por el gateway 192.168.1.1 en  nuestro caso  solo compara trafico que vaya dirijido  hacia internet
 


 

en la regla de ruteo de la  wan 2   cambiamos la distancia administrativa  a  2  si huvieran mas lienas solo se agregan y se pone  distancia 3   y  luego 4  y asi sucesivamente



Linea 2



y repetimos el procedimiento  con la otra linea  creando  la misma regla para añadir la marca de ruteo  pero variando el gateway y el nombre de  la marca de ruteo , una observacion en todas la reglas que pongamos una marca de ruteo  se deve  poner siempre en distancia administritavas con distancia  1  ya que esa regla solo se usa  para espesificar  la marca de ruteo




ahora podemos apreciar que por cada gateway tenemos 2 reglas una para  una para espesificar la marca de ruteo y otra espesificando la distancia esto nos garantiza que si algun momento dejamos de tener conectividad  por un  gateway  automaticamente todo el trafico de la red lan recaera  por el otro gateway activo y dejara de enviar conexiones por la linea inalcansable



/ip route
add check-gateway=ping comment="Ruteo wan 1" distance=1 gateway=192.168.1.1 routing-mark=to_ether1
add check-gateway=ping comment="Ruteo wan 2" distance=1 gateway=192.168.9.1 routing-mark=to_ether2
add check-gateway=ping comment="Wan 1" distance=1 gateway=192.168.1.1
add check-gateway=ping comment="Wan 2" distance=2 gateway=192.168.9.1

paso 8

Marcado de conexiones

Nos dirijimos a IP/Firewall/Mangle y le damos al simbolo +

pasare a explicar las obciones que tocaremos en esta configuracion

PREROUTING = indica  antes que el paquete ingrese  al router
IN.INTERFACE =  indica la interface de entrada del trafico

en esta pestaña nos  dice que todo paquete antes que ingrese al router por la ether1 (que viene a hacer nuestra Wan 1) esto nos garantiza un marcado de conexiones por cada wan




marcalos con una marca de conexion ether1_conn(impórtante dejar marcado el passthrough)

hacemos la misma regla  pero con la otra interface  de la wan y con otra marca de ruteo para poder diferenciarlas y identificarlas en proximas configuraciones







/ip firewall mangle
add action=mark-connection chain=prerouting comment="Marca de conexiones" in-interface=ether1 new-connection-mark=ether1_conn
add action=mark-connection chain=prerouting in-interface=ether2 new-connection-mark=ether2_conn

Paso 9

Creamos otra regla pero ahora en chain  elijimos output

Output = todo lo que salga del router
Connection Mark = indica la marca de conexion que que debe contener el paquete ( marca que pusimos en la regla anterior

esto quiere desir que todo paquete saliente  con la marca de conexion de ether1_conn




le añadimos  la marca de ruteo  to_ether1 ,recuerden que la marca de ruteo esta relacionada a un gateway , el paquete antes de entrar por la wan  lo marca con una marca de conexion y luego a todos los que tengan  esa marca de conexion  les pondra una marca de ruteo para que la conexion entre por lina y salga por la misma linea  pero esto no garantiza  que la comunicacion se mantendra por la misma limea , podria entrar por una wan1 y sale por la wan1 pero al regresar  podria entrar por la wan 1 o la wan 2 .


repetimos la regla para la otra interface  variando  la ether y la marca de connexion y  de ruteo




add action=mark-routing chain=output comment=Salida connection-mark=ether1_conn new-routing-mark=to_ether1
add action=mark-routing chain=output connection-mark=ether2_conn new-routing-mark=to_ether2

Paso 10

En esta regla haremos lo que en si  es el balanceo de carga  ,esta regla nos dice todo trafico antes que ingrese por la interface ether5 que biene ha ser nuestra red lan no la marquemos

 

Divicion de carga de trafico

Desde el maravilloso mundo de las frames y los bits ... Llego el balanceo ,las reglas donde inician la magia

en la pestaña advanced definiremos la divicion de carga que se hara a cada  linea , en el balanceo pcc siempre usaremos  both address y para hacer el calculo de divicion , es un  complejo problema matematico  que puede ser muy dificil de realizar pero  se que algunos  podremos entender y interpretar este problema

numero de megas en total de todas tus lienas / la linea  que tenga menor cantidad de megas = numero de reglas

en nuestro caso tenemos  40 megas en total ,10 de la primera linea y 30 de la segunda entonces hacemos nuestra compleja ecuacion matematica

40 / 10 = 4
eso quiere decir que  haremos 4  reglas  1 dirigida a la liena de 10 megas y las otras 3 para la otra linea de 30 megas y asi poder dividir las conexiones entre las lineas que tenemos , la linea que tiene 30 megas aguantara  mas carga de conexiones(carga)  que el de 10 megas por tener mas capacidad

Al iniciar el conteo se cuenta del 0

4/0
4/1
4/2
4/3

siempre se mantiene el numero de total de reglas





se selecciona el Address Type  en local y se selecciona  la obcion Invert  , esta opcion es para que no marque nuestro trafico lan interno
 


en esta opcion  marcaremos nuevamente nuestra conexion  con el nombre que anteriormente usamos para marcar nuestra conexion anterior,  marcaremos la conexion perteneciente a cada liena ,a la linea de 10 mega le pondremos una marca de coneccion con ether1_conn que es  la misma que se uso anteriormente despues  creamos otras tres  iguales  pero bariando en la pestaña advance  en both address haciendo la divicion correcta  y en Action  marcando al coneccion a  ether2_conn las tres reglas de esta manera cargaremos 25% de las conexiones  x 3  por tener 3 veces mas capasidad que la otra linea de 10 megas 

 


despues de haver completado las reglas de divicion de conexiones  ,nos quedaran de esta manera
en estas reglas es en donde vemos la divicion de conexiones hacia nuetsras lineas wans ,hacemos tres reglas  con la misma marca de conexion  para que tome el 75% de las conexiones de la red lan 
estas reglas nos dicen que todo trafico  antes que ingrese al router por la interface ether 5 (red lan)  hace la divicion  descrita en bot address y que le ponga su marca de conexion respectiva

  


add action=mark-connection chain=prerouting comment="Wan (1) 10 megas" connection-mark=no-mark dst-address-type=!local in-interface=ether5 new-connection-mark=ether1_conn \
    per-connection-classifier=both-addresses:4/0
add action=mark-connection chain=prerouting comment="Wan (2) 30 megas" connection-mark=no-mark dst-address-type=!local in-interface=ether5 new-connection-mark=ether2_conn \
    per-connection-classifier=both-addresses:4/1
add action=mark-connection chain=prerouting connection-mark=no-mark dst-address-type=!local in-interface=ether5 new-connection-mark=ether2_conn per-connection-classifier=\
    both-addresses:4/2
add action=mark-connection chain=prerouting connection-mark=no-mark dst-address-type=!local in-interface=ether5 new-connection-mark=ether2_conn per-connection-classifier=\
    both-addresses:4/3

Paso 11

Seguiremos trabajando con la red lan  en esta regla basicamente le diremos que por la  misma interface wan  que ingresa la conexion salga.

Esta regla queire desir todo paquete antes de ingresar al router por la ether 5 (red lan) que contenga la marca de conexion ether1_conn 


 

asociala  a la marca de ruteo to_ether1 ,recordar que la marca de ruteo esta amarrado con un gateway



add action=mark-routing chain=prerouting connection-mark=ether1_conn in-interface=ether5 new-routing-mark=to_ether1
add action=mark-routing chain=prerouting connection-mark=ether2_conn in-interface=ether5 new-routing-mark=to_ether2


Con esto  ya tendremos  nuestro balanceo  funcionando al 100 %   ahora veremos temas adicionales  a un balanceo de carga

Paso 12

Como comprobar la calidad de cada  linea en tu balanceo

Un problema muy comun es escuchar la frase tipica que siempre escucho  (mi red esta lenta) cuando nos encontramos con una red  con un router balanceador  lo primero que tenemos que  revisar son las lineas wans, ver si todas las lineas estan activas y  revisar su latencia , hacer un ping constante nos mostrara esos datos  que nos serviran para poder hacer nuestro descarte , saber que linea nos esta  causando problemas ,  saber si esta caida o no , nos dirijimos a  la pestaña New Terminal y digitamos en la consola

ping 8.8.8.8 routing-table=to_ether2

8.8.8.8 =  es la ip a la que se quiere hacer  el ping
route-table =  es el comando que se usa antes de especificar una  marca de ruteo de la linea que queremos testear
to_ether2 = indica el nombre de la marca de ruteo  asociada  a la linea que se quieres testear

Haciendo un  ping

 PING 

Verifica la conectividad de nivel de IP a otra computadora TCP / IP mediante el envío de mensajes de solicitud de ekko del protocolo de mensajes de control de Internet (ICMP). Se muestra la recepción de los mensajes de respuesta de ekko correspondientes, junto con los tiempos de ida y vuelta

Ping es el comando TCP / IP principal utilizado para verificar  problemas de conectividad, accesibilidad


Host =  nos indica la  ip a la que estamos haciendo ping
Sise  =  indica el tamaño del paquete
Ttl    =  tiempo de vida del paquete
Time =  tiempo de respuesta del ping ( este valor nos interesa mucho ya que si es muy elevado  esto puede indicar saturacion o algun problema de tu  linea  y podria ser causa de la lentitud) en este  imagen  vemos que el tiempo de respuesta esta en lo normal  si en caso muestra mas de 120ms eso significaria retraso .





Ahora realizamos esta prueba con todas nuestras lienas para comprovar que tenemos salida y enterarnos que linea es la que mejor nos funciona , luego de comprobar generaremos trafico para verificar  que se este haciendo el balanceo de carga   nos vamos a interfaces y  veremos el trafico como se comparta en nuestras interfaces wans  ,por  ser nuestra  wan 1 de 10 megas  y la wan 2 de 30 megas es evidente que la wan 2 tendra mas carga de trafico ya que es de mayor capacidad   que la primera wan.




En  la pestaña   conections del firewall podremos ver la divicion de las conexiones en tiempo real que hace nuestro router hacia las interfaces wans


con esto terminamos  nuestro balanceo de carga

Excluir a clientes del balanceo de carga

Ahora  bien en  algunos casos  se quiere excluir a un cliente del balanceo y hacer  que salga por una linea wan espesifica, en caso una linea tenga mas prioridad o  tenga alguna  intermitencia por  una por alguna razon , o se quiera digijir un segmento de red  por una linea y otro segmento de red por la otra linea para esto nos dirijiremos ip/firewall/mangle

simulando que la ip  192.168.80.239 es el cliente a  trabajar, en caso sean algunas ips se  trabajarian con  Address List

Script de la regla

add action=mark-routing chain=prerouting disabled=yes dst-address-type=!loca
    new-routing-mark=to_ether2 passthrough=yes src-address=192.168.80.239




to_ether2 =  indica la marca de ruteo que se puso en ip/route  lo cual esta vinculado a una linea wan

esta regla se coloca delante del balanceo para que el firewall machee  primero esa regla y el trafico que tenga como origen esa ip no  pase por el balanceo.







script

/ip address
add address=192.168.1.2/24 comment="Wan 1" interface=ether1 network=192.168.1.0
add address=192.168.9.2/24 comment="Wan 2" interface=ether2 network=192.168.9.0
add address=10.10.10.1/24 comment=Lan interface=ether5 network=10.10.10.0

/ip firewall nat
add action=masquerade chain=srcnat comment="Wan 1" out-interface=ether1
add action=masquerade chain=srcnat comment="Wan 2" out-interface=ether2

/ip route
add check-gateway=ping comment="Ruteo wan 1" distance=1 gateway=192.168.1.1 \
    routing-mark=to_ether1
add check-gateway=ping comment="Ruteo wan 2" distance=1 gateway=192.168.9.1 \
    routing-mark=to_ether2
add check-gateway=ping comment="Wan 1" distance=1 gateway=192.168.1.1
add check-gateway=ping comment="Wan 2" distance=2 gateway=192.168.9.1

/ip firewall mangle
add action=mark-connection chain=prerouting comment="Marca de conexiones" \
    in-interface=ether1 new-connection-mark=ether1_conn
add action=mark-connection chain=prerouting in-interface=ether2 \
    new-connection-mark=ether2_conn
add action=mark-routing chain=output comment=Salida connection-mark=ether1_conn \
    new-routing-mark=to_ether1
add action=mark-routing chain=output connection-mark=ether2_conn \
    new-routing-mark=to_ether2
add action=mark-connection chain=prerouting comment="Wan (1) 10 megas" \
    connection-mark=no-mark dst-address-type=!local in-interface=ether5 \
    new-connection-mark=ether1_conn per-connection-classifier=\
    both-addresses:4/0
add action=mark-connection chain=prerouting comment="Wan (2) 30 megas" \
    connection-mark=no-mark dst-address-type=!local in-interface=ether5 \
    new-connection-mark=ether2_conn per-connection-classifier=\
    both-addresses:4/1
add action=mark-connection chain=prerouting connection-mark=no-mark \
    dst-address-type=!local in-interface=ether5 new-connection-mark=ether2_conn \
    per-connection-classifier=both-addresses:4/2
add action=mark-connection chain=prerouting connection-mark=no-mark \
    dst-address-type=!local in-interface=ether5 new-connection-mark=ether2_conn \
    per-connection-classifier=both-addresses:4/3
add action=mark-routing chain=prerouting connection-mark=ether1_conn \
    in-interface=ether5 new-routing-mark=to_ether1
add action=mark-routing chain=prerouting connection-mark=ether2_conn \
    in-interface=ether5 new-routing-mark=to_ether2